[AHK]LF2鎖Win、Esc外帶老闆鍵

遊戲中，視窗鍵、Escape鍵無效，連按兩下CapsLock老闆鍵 XD

以下是代碼……有附註釋

37

SetStoreCapsLockMode, Off ;設定Off，Send,{CapsLock}才有效
DetectHiddenWindows, On   ;能存取隱藏後的視窗
SetWorkingDir, D:\LF2_v2.0 ;設定LF2的資料夾位置
lf2:="Little Fighter 2"   ;設定視標題
hidding:=0   ;設定開始時，視窗還未被隱藏
Run, lf2.exe ;執行LF2
WinWait, %lf2%     ;等待LF2開啟
WinWaitClose, %lf2%        ;若LF2關閉
ExitApp       ;程式結束

#IfWinActive, Little Fighter 2 ;以下按鍵只對LF2有效
  LWin::return       ;左邊視窗鍵失效
  RWin::return       ;右邊視窗鍵失效
  Esc::return        ;Esc鍵失效
#IfWinActive         ;以下按鍵都有效

CapsLock::           ;設定快速鍵第一鍵CapsLock
  Send, {CapsLock}   ;按下後，傳送一個CapsLock鍵給電腦
  KeyWait, CapsLock  ;等待CapsLock鍵被放開
  KeyWait, CapsLock, D T0.25          ;等待第二鍵CapsLock在0.25秒內被按下
  If ErrorLevel      ;若超時
    return           ;return
  Else               ;偵測到CapsLock被按下
  {
    Send, {CapsLock} ;傳送一個CapsLock給電腦
    If hidding       ;若LF2隱藏中
    {
      WinShow, %lf2% ;顯示LF2
      hidding:=0
    }
    Else        ;若未被隱藏
    {
      WinHide, %lf2%    ;隱藏它
      hidding:=1
    }
  }
return

存成.ahk的純文字文件，用AutoHotkey開啟就行了！

已編譯的exe執行檔︰
http://www.multiupload.com/APU3QMXYFJ

裡面有「setting.txt」，可以更改LF2所在目錄、快捷鍵。